dotfiles/zsh/.config/zsh/completions.zsh

#!/bin/zsh

_lazy_load_completion() {
    local cmd="$1"
    local completion_cmd="$2"

    eval "${cmd}() {
        unfunction $cmd
        eval \"\$($completion_cmd)\"
        $cmd \"\$@\"
    }"
}

for completion_file in ~/.local/share/zsh/*-autocomplete.zsh(N); do
    if [ -f "$completion_file" ]; then
        source "$completion_file"
    fi
done

if command -v eza &> /dev/null; then 
    compdef eza=ls
fi

if command -v kubefwd &> /dev/null; then 
    _lazy_load_completion kubefwd "kubefwd completion zsh"
fi

if command -v bombadil &> /dev/null; then 
    _lazy_load_completion bombadil "bombadil generate-completions zsh"
fi

if command -v rop &> /dev/null; then 
    eval "$(rop completion zsh)"
fi

if command -v goq &> /dev/null; then 
    eval "$(goq completion zsh)"
fi

if command -v drop &> /dev/null; then 
    eval "$(drop completion zsh)"
fi

if command -v mora &> /dev/null; then 
    eval "$(mora completion zsh)"
fi

_kf_completion() {
    local -a contexts
    contexts=($(kubectx 2>/dev/null | sed 's/-read$//; s/-security$//' | sort -u))

    if [[ ${#contexts[@]} -gt 0 ]]; then
        _values 'cluster' "${contexts[@]}"
    fi
}

_rmq_passwd_completion() {
    local -a environments
    environments=($(kubectl config get-contexts -o name 2>/dev/null | grep '^oc-.*-eks-cluster$' | sed 's/^oc-//; s/-eks-cluster$//' | sort -u))

    if [[ ${#environments[@]} -gt 0 ]]; then
        _describe 'environments' environments
    fi
}

_yay_completion() {
    local cur prev opts
    COMPREPLY=()
    cur="${COMP_WORDS[COMP_CWORD]}"
    prev="${COMP_WORDS[COMP_CWORD-1]}"

    opts="-Syyu -Syu -Ss -S -R -Q -Si -Sc help install remove list clean"

    COMPREPLY=( $(compgen -W "${opts}" -- ${cur}) )
    return 0
}

_yay_zsh_completion() {
    local -a opts
    opts=(
        '-Syyu:Update system'
        '-Syu:Update system'
        '-Ss:Search packages'
        '-S:Install system-wide'
        '-R:Remove package'
        '-Q:List installed'
        '-Si:Package info'
        '-Sc:Clean cache'
        '-p:Open nix-shell with packages'
        'help:Show help'
        'install:Install to user env'
        'remove:Remove from user env'
        'list:List installed packages'
        'clean:Clean nix store'
        'shell:Start nix-shell with packages'
    )
    _describe 'yay commands' opts
}

compdef _kf_completion kf
compdef _rmq_passwd_completion rmq-passwd

if [[ -n "${BASH_VERSION:-}" ]]; then
    complete -F _yay_completion yay
elif [[ -n "${ZSH_VERSION:-}" ]]; then
    compdef _yay_zsh_completion yay
fi